Source code
Revision control
Copy as Markdown
Other Tools
/* This Source Code Form is subject to the terms of the Mozilla Public
* License, v. 2.0. If a copy of the MPL was not distributed with this
* file, You can obtain one at http://mozilla.org/MPL/2.0/. */
import static org.mozilla.conventions.BuildConfigKt.updateExtensionVersion
plugins {
alias(libs.plugins.dependency.analysis)
alias(libs.plugins.kotlin.android)
alias(libs.plugins.kotlin.compose)
}
apply plugin: 'com.android.library'
android {
sourceSets {
androidTest {
// Use the same resources as the unit tests
resources.srcDirs += ['src/test/resources']
}
}
buildFeatures {
compose = true
}
namespace = 'mozilla.components.browser.icons'
}
tasks.register("updateBuiltInExtensionVersion", Copy) { task ->
updateExtensionVersion(task, 'src/main/assets/extensions/browser-icons', rootProject.ext.config.componentsVersion)
}
// Make sure DAGP asset-source exploding happens after ExtensionVersion tasks
tasks.matching { it.name.startsWith("explodeAssetSource") }.configureEach { t ->
t.dependsOn(tasks.named("updateBuiltInExtensionVersion"))
}
dependencies {
api project(':components:support-images')
implementation project(':components:browser-state')
implementation project(':components:concept-base')
implementation project(':components:concept-engine')
implementation project(':components:concept-fetch')
implementation project(':components:support-ktx')
implementation libs.androidsvg
implementation libs.androidx.annotation
implementation platform(libs.androidx.compose.bom)
implementation libs.androidx.compose.material3
implementation libs.androidx.compose.ui
implementation libs.androidx.core.ktx
implementation libs.androidx.palette
implementation libs.disklrucache
implementation libs.kotlinx.coroutines
testImplementation project(':components:lib-fetch-httpurlconnection')
testImplementation project(':components:lib-fetch-okhttp')
testImplementation project(':components:support-test')
testImplementation libs.androidx.test.core
testImplementation libs.androidx.test.junit
testImplementation libs.kotlin.reflect
testImplementation libs.kotlinx.coroutines.test
testImplementation libs.mockwebserver
testImplementation libs.okhttp
testImplementation libs.okio
testImplementation libs.robolectric
androidTestImplementation libs.androidx.test.core
androidTestImplementation libs.androidx.test.rules
androidTestImplementation libs.androidx.test.runner
androidTestImplementation libs.kotlinx.coroutines.test
}
apply from: '../../../common-config.gradle'
apply from: '../../../publish.gradle'
ext.configurePublish(config.componentsGroupId, project.name, project.ext.description)
preBuild.dependsOn updateBuiltInExtensionVersion